//// Save data in partitioned database

// save a sequentially partitioned database table

db = database("C:/DolphinDB/Data/seqdb", SEQ, 8)
USstocks = loadTextEx(db, "USstocks",, "C:/DolphinDB/Data/USstocks.csv");


// save a range partitioned database table

db=database("C:/DolphinDB/Data/rangedb1", RANGE,  `A`F`N`T`ZZZZ)
USstocks = loadTextEx(db, "USstocks",`TICKER, "C:/DolphinDB/Data/USstocks.csv");

n=1000000
ID=rand(10, n)
x=rand(1.0, n)
t=table(ID, x);
db=database("C:/DolphinDB/Data/rangedb2", RANGE,  0 5 10)
pt = db.createPartitionedTable(t, `pt, `ID)
pt.append!(t);
pt=loadTable(db,`pt)
select count(*) from pt;


// save a value partitioned database table

n=1000000
month=take(2000.01M..2016.12M, n)
x=rand(1.0, n)
t=table(month, x);
db=database("C:/DolphinDB/Data/valuedb", VALUE, 2000.01M..2016.12M)
pt = db.createPartitionedTable(t, `pt, `month)
pt.append!(t);
pt=loadTable(db,`pt)
select count(x) from pt;


// save a hierarchically partitioned database table

n=1000000
ID=rand(100, n)
dates=2017.08.07..2017.08.11
date=rand(dates, n)
x=rand(10.0, n)
t=table(ID, date, x);
dbDate = database(, VALUE, 2017.08.07..2017.08.11)
dbID=database(, RANGE, 0 50 100)
db = database("C:/DolphinDB/Data/hierDB", HIER, [dbDate, dbID])
pt = db.createPartitionedTable(t, `pt, `date`ID)
pt.append!(t);
pt=loadTable(db,`pt)
select count(x) from pt;
count_x
-------
1000000